為報表加入參數時的注意事項

一般來說
報表的參數通常用在報表在過濾資料或者查詢資料時
也就是我們把Query database與bind通通交給Crystal Report做
但是如果我們是利用程式手動餵DataTable給ReportDocument
再把這個ReportDocument指為CrystalReportViewer的ReportSource
參數還是可以具體的以"參數欄位"show值在報表上
例如:產生週、月、季報表時,除了基本的報表日期,
我們可以將user前一個步驟給定的週、月、季或年呈現在報表
讓閱讀報表時更明白資料內容。
指定報表參數三步驟
(1)在報表設計(.rpt)建立參數欄位,並拉至報表畫面中

(2)在負責產生報表內容的class檔中，建立一個function設定報表參數,例如:

 'paramName=報表參數名稱,與rpt檔中的"參數欄位"相同
 'paramValue=報表參數值
 Public Sub AddParameter(ByVal paramName As String, ByVal paramValue As String)
        Dim ParamField As New ParameterField()
        Dim ParamDiscreteValue As New ParameterDiscreteValue()
        Dim ParamFields As New ParameterFields()

        ParamField.ParameterFieldName = paramName
        ParamDiscreteValue.Value = paramValue
        ParamField.CurrentValues.Add(ParamDiscreteValue)
        ParamFields.Add(ParamField)
        '把Show報表的CrystalReportViewer物件的ParameterFieldInfo屬性指定為
         '剛建立的ParameterFields物件
        Me.RptViewer.ParameterFieldInfo = ParamFields

        'release resource
        ParamField = Nothing
        ParamFields = Nothing
        ParamDiscreteValue = Nothing
    End Sub

簡單來說報表參數的架構是:
   ParameterFields集合物件下包含多個ParameterField
   一個ParameterField的CurrentValues屬性(Class ParameterValues)
   又是集合多個ParameterValue物件....
   (上面我以ParameterDiscreteValue物件表示,因為ParameterValue有兩個子類別:
    ParameterDiscreteValue與ParameterRangeValue。)
   感覺設定ParameterValue有點麻煩
   有ParameterFields、ParameterField
   又有ParameterValues、ParameterValue
   可以理解報表參數可能不只一個,但是為何Value也要用個集合來放??
   用MSDN的例子說明:
   假若銷售統計報表有"City"這個參數
   想要知道Taipei、Kaohsiung這兩個city的銷售情況時
   就可以分別指定兩個ParameterValue物件的Value為Taipei、Kaohsiung.....right?
   因為報表參數的設計理念是透過報表執行查詢與過濾資料
   如果只是單純呈現參數欄位是比較看不出它的作用的

(3)在設定CrystalReportViewer.ReportSource後執行步驟(2)的function

   雖然,根據MSDN說明,在指定ReportSource屬性前要先指定ParameterFieldInfo,
   否則會出現要求輸入參數值的畫面。例如:

不過,經過測試後
反而是先指定指定ReportSource屬性再指定ParameterFieldInfo才不會出錯!!!
Ok,如果是WindowForm到這一步已經大功告成了
但是如果你像我一樣是寫web專案
你會發現操作CrystalReportViewer上的tool bar時報表內容會消失
顯然這與web先天無狀態有關
要處理這個問題只好把session搬出來了
我的作法是在設定CrystalReportViewer.ReportSource時
將ReportDocument的資料(DataTable)寫入Session:

  Public Sub ConfigReport(ByVal paramRptFileName As String, ByVal paramRptData As DataTable)
        Me._ReportDocument = New ReportDocument()
        Session("RptFileName") = Me.GetReportPhysicPath(paramRptFileName)
        Me._ReportDocument.Load(Session("RptFileName"))
        Me._ReportDocument.SetDataSource(paramRptData)
        Me.RptViewer.ReportSource = Me._ReportDocument
        Me.RptViewer.DataBind()
        Session("ReportData") = paramRptData
    End Sub

本來想直接把ReportDocument物件寫入session
省掉Load、SetDataSource步驟,可惜失敗...只好用2個session分別記錄DataTable與rpt檔名
然後在page事件中再餵一次報表資料:

Protected Sub Page_Init(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Init
        If IsPostBack Then
            If Session("ReportData") IsNot Nothing Then
                Me._ReportDocument = New ReportDocument()
                Me._ReportDocument.Load(Session("RptFileName"))
                Me._ReportDocument.SetDataSource(Session("ReportData"))
                Me.RptViewer.ReportSource = Me._ReportDocument
                Me.RptViewer.DataBind()
            Else
                RaiseEvent ReportSessionTimeOut()
            End If
        End If
    End Sub

這裡有個小訣竅
千萬不要寫在PageLoad事件中
否則執行時會有意想不到的結果產生
(我的情況是換頁時頁碼會亂跳!!)